Envoi d’un fichier sur un serveur FTP via Microsoft Excel

J’avais besoin de pouvoir envoyer un fichier sur un serveur FTP après avoir fait une série de traitements via Microsoft Excel. Ci-dessous, vous trouverez le code VBA que j’ai adapté pour parvenir à mes fins.

Ici, la fonction EnvoiFichierFTP() est affectée à un bouton pour déclencher l’envoi d’un fichier texte nommé « test.txt » présent sur mon bureau pour l’envoyer à la racine d’un serveur FTP.

Il suffit d’adapter les 5 valeurs contenues dans « Définition des paramètres FTP », puis dans « Définition des emplacements du fichier local et distant ».

' Open the Internet object
Private Declare PtrSafe Function InternetOpen Lib "wininet.dll" Alias "InternetOpenA" _
(ByVal sAgent As String, ByVal lAccessType As Long, ByVal sProxyName As String, _
ByVal sProxyBypass As String, ByVal lFlags As Long) As Long

' Connect to the network
Private Declare PtrSafe Function InternetConnect Lib "wininet.dll" Alias "InternetConnectA" _
(ByVal hInternetSession As Long, ByVal sServerName As String, _
ByVal nServerPort As Integer, ByVal sUsername As String, _
ByVal sPassword As String, ByVal lService As Long, _
ByVal lFlags As Long, ByVal lContext As Long) As Long

' Get a file using FTP
Private Declare PtrSafe Function FtpGetFile Lib "wininet.dll" Alias "FtpGetFileA" _
(ByVal hFtpSession As Long, ByVal lpszRemoteFile As String, _
ByVal lpszNewFile As String, ByVal fFailIfExists As Boolean, _
ByVal dwFlagsAndAttributes As Long, ByVal dwFlags As Long, _
ByVal dwContext As Long) As Boolean

' Send a file using FTP
Private Declare PtrSafe Function FtpPutFile Lib "wininet.dll" Alias "FtpPutFileA" _
(ByVal hFtpSession As Long, ByVal lpszLocalFile As String, _
ByVal lpszRemoteFile As String, ByVal dwFlags As Long, _
ByVal dwContext As Long) As Boolean

' Close the Internet object
Private Declare PtrSafe Function InternetCloseHandle Lib "wininet.dll" _
(ByVal hInet As Long) As Integer

Sub EnvoiFichierFTP()

   Dim HwndConnect As Long
   Dim HwndOpen As Long, MyFile
   Dim ftpAddress As String
   Dim ftpUser As String
   Dim ftpPassword As String
   Dim ftpLocalFilepath As String
   Dim ftpRemoteFilepath As String

   ' Définition des paramètres FTP
   ftpAddress = "80.80.80.1"
   ftpUser = "monUtilisateur"
   ftpPassword = "MotDePasse"
   
   ' Définition des emplacements du fichier local et distant
   ftpLocalFilepath = "C:\Users\Lumo\Desktop\test.txt"
   ftpRemoteFilepath = "./test.txt"
   
   ' -----------------
   ' NE PLUS TOUCHER
   ' -----------------

   ' Initialisation de la connexion FTP
   HwndOpen = InternetOpen("connexionFTP", 0, vbNullString, vbNullString, 0)

   ' Connexion au serveur FTP
   HwndConnect = InternetConnect(HwndOpen, ftpAddress, 21, ftpUser, ftpPassword, 1, 0, 0)

   If HwndConnect = 0 Then
    MsgBox ("Une erreur est survenue lors de la connexion. Vérifiez les informations de connexion.")
    InternetCloseHandle HwndConnect
    InternetCloseHandle HwndOpen
    Exit Sub
   End If

   ' Envoi du fichier
   HwndPut = FtpPutFile(HwndConnect, ftpLocalFilepath, ftpRemoteFilepath, &H0, 0)
   If HwndPut = 0 Then
    MsgBox ("Une erreur est survenue lors de l'envoi du fichier. Vérifiez les emplacements des fichiers")
   End If

   ' Fermeture des connexions
   InternetCloseHandle HwndConnect
   InternetCloseHandle HwndOpen
   
End Sub